Dev Archipelago: Translate Basics islands to Spanish

addons/threadbare_editor/plugin.cfg

@@ -1,7 +1,7 @@
 [plugin]
 
 name="ThreadbareEditor"
-description="Adds an editor debugger."
+description="Threadbare editor integrations: a debugger and a translation parser."
 author="The Threadbare Authors"
 version=""
 script="plugin.gd"

addons/threadbare_editor/plugin.gd

@@ -5,16 +5,27 @@ class_name ThreadbareEditorPlugin
 extends EditorPlugin
 
 const ThreadbareDebugger := preload("res://addons/threadbare_editor/threadbare_debugger.gd")
+const QuestTranslationParser := preload(
+	"res://addons/threadbare_editor/quest_translation_parser.gd"
+)
 
 var threadbare_debugger: EditorDebuggerPlugin
+var quest_translation_parser: EditorTranslationParserPlugin
 
 
 func _enter_tree() -> void:
 	threadbare_debugger = ThreadbareDebugger.new()
 	add_debugger_plugin(threadbare_debugger)
 
+	quest_translation_parser = QuestTranslationParser.new()
+	add_translation_parser_plugin(quest_translation_parser)
+
 
 func _exit_tree() -> void:
 	if threadbare_debugger:
 		remove_debugger_plugin(threadbare_debugger)
 		threadbare_debugger = null
+
+	if quest_translation_parser:
+		remove_translation_parser_plugin(quest_translation_parser)
+		quest_translation_parser = null

addons/threadbare_editor/quest_translation_parser.gd

@@ -0,0 +1,32 @@
+# SPDX-FileCopyrightText: The Threadbare Authors
+# SPDX-License-Identifier: MPL-2.0
+@tool
+extends EditorTranslationParserPlugin
+## Extracts the translatable strings of a [Quest] resource.
+##
+## A [Quest] is a custom resource, so by default is not recognized by the translation system.
+## This parser makes it possible, so adding a quest.tres to the list of translatable
+## files puts its title and description in the catalog.
+
+const TITLE_COMMENT := "Quest title"
+const DESCRIPTION_COMMENT := "Quest description"
+
+
+func _get_recognized_extensions() -> PackedStringArray:
+	return ResourceLoader.get_recognized_extensions_for_type("Quest")
+
+
+func _parse_file(path: String) -> Array[PackedStringArray]:
+	var messages: Array[PackedStringArray] = []
+
+	# Skip .tres files that aren't Quests.
+	var quest := ResourceLoader.load(path, "", ResourceLoader.CACHE_MODE_IGNORE) as Quest
+	if not quest:
+		return messages
+
+	if quest.title:
+		messages.append(PackedStringArray([quest.title, "", "", TITLE_COMMENT]))
+	if quest.description:
+		messages.append(PackedStringArray([quest.description, "", "", DESCRIPTION_COMMENT]))
+
+	return messages

addons/threadbare_editor/quest_translation_parser.gd.uid

@@ -0,0 +1 @@
+uid://v8n7t54c7iqy